Constructing MW patterns

4 Pages·1994·0.056 MB·English

Stocks & Commodities V13 (357): Constructing MW patterns
CONSTRUCTING MW PATTERNS
Here are the formulas for identifying MW patterns using a Microsoft Excel spreadsheet. Columns A through E
contain the date, open, high, low and close of the data you wish to analyze. In sidebar Figures 1 and 2, the data is
September 1994 Treasury bond futures. Cell G1 has the filter size, which will be 0.01, but first, name the cell as a
filter, using the insert-name-define keystroke sequence (see your manual regarding defining a name for a cell) and
then enter 0.01.
SIDEBAR FIGURE 1: MW PATTERNS. Here's an example of columns A through L for the Excel
spreadsheet. The data is September 1994 Treasury bond futures.
Copyright (c) Technical Analysis Inc.
Stocks & Commodities V13 (357): Constructing MW patterns
SIDEBAR FIGURE 2: MW PATTERNS. Here's a continuation of the same spreadsheet for columns M
through W.
Next, set up the designation of the wave with u indicating an upwave and d indicating a downwave. In cell H2,
enter U.
In cell H3, enter the following formula and copy down:
=IF(AND(H2="u",C3>I2),H2,IF(AND(H2="d",D3<I2),H2,
IF(AND(H2="u",D3<J2),"d",IF(AND(H2="d",C3>J2),"u",H2))))
Column I locates the apex of the move. Enter into cell I2 =C2, then enter into cell I3 the following formula and copy
down:
=IF(H3=H2,IF(H3="u",MAX(C3,I2),MIN(D3,I2)),
IF(AND(H3="d",H2="u"),D3,IF(AND(H3<>H2,H3="u"),C3,
IF(AND(H3<>H2,H3="d"),D3,I2))))
Column J determines the date of the change in direction. Enter into J2 the following formula and copy down:
=IF(H2="u",I2*(1-filt),IF(H2="d",I2*(1+filt),J1))
The beginning date of this move, or Start_Date, is the apex date of the last move and is found in column K. Enter
into K2:
=A2
Then in K3, enter the following formula and copy down:
=IF(H3=H2,K2,L2)
Copyright (c) Technical Analysis Inc.
Stocks & Commodities V13 (357): Constructing MW patterns
Then the date that the apex of this move is achieved is determined in column L. Enter into L2:
=A2
Then in cell L3, enter the following formula and copy down:
=IF(AND(H3=H2,H3="u"),IF(C3>=I2,A3,L2),IF(AND
(H3=H2,H3="d"),IF(D3<=I2,A3,L2),IF(H3<>H2,A3,L2)))
The last date that this move had in its current designation is in column M. In cell M2, enter the following formula and
copy down:
=IF(H2<>H3,L2,"")
The inception point is the starting value of this wave and is determined in column N. Enter into cell N2:
=I2
Then in cell N3, enter the following formula and copy down:
=IF(H3<>H2,I2,N2)
The ending point is the last value the market traded at before switching to another designation and can be found in
column O. In cell O2, enter the following formula and copy down:
=IF(H2<>H3,I2,"")
Next, each of the points for the MW pattern are detailed. The first price pattern (PP1) is the most current apex of the
MW pattern and is found in column P. Enter into cell P2 the following formula and copy down:
=I2
PP2 is the second-most current apex composing the MW pattern. Leave cell Q2 blank, enter into cell Q3 the
following formula and copy down:
=IF(H3<>H2,P2,Q2)
PP3 through PP5 are the third through the fifth most recent apexes composing the pattern, respectively. Leave cell
R2 blank. In cell R3, enter the following formula:
=IF(Q3<>Q2,Q2,R2)
Copy cell R3 and paste from cell R3 to T3, then copy down the three columns to make PP3 through PP5. Leave R2
to T2 blank. In cell U3, we are constructing the MW pattern using the Excel RANK() function. Enter into cell U3 the
following formula and copy down:
=RANK(P3,P3:T3)&RANK(Q3,P3:T3)&RANK(R3,P3:T3)
&RANK(S3,P3:T3)&RANK(T3,P3:T3)
Column V is the net working days between the inception date and the apex date. In cell V3, enter the following
formula and copy down:
=IF(H3<>H4,NETWORKDAYS(K3,L3,),"")
If a holiday occurs during the interim, add an extra argument to the formula in V3 as follows:
=IF(H3<>H4,NETWORKDAYS(K3,L3,1)
Copyright (c) Technical Analysis Inc.
Stocks & Commodities V13 (357): Constructing MW patterns
The "1" indicates a holiday is present. The percentage change from inception point to apex of the most recent wave is
listed in column W. Enter the following formula into cell W3 and copy down:
=IF(H3<>H4,(O3-N3)/N3,"")
-S.W.B.
end
end
end
end
end
end
end
end
Copyright (c) Technical Analysis Inc.